Thumbnails mit Photoshop

Thumbnails erstellen

#! /usr/bin/perl

use strict;
use warnings;
use Win32::OLE;
use Win32::OLE::Const 'Adobe Photoshop';
use File::Spec;
use Getopt::Long;

my $size = 350;
my $dir;
my $help;

GetOptions('-d=s' => \$dir,
           '-s=n' => \$size,
           '-h'   => \$help,);

if($help || !$dir){
  print qq~
  Usage: $0 -d <directory> [-s <width>][-h]
~;
  exit(0);
}

opendir(DIR,$dir) or die $!;
my @files = grep{$_ !~ /^\.\.?$/}readdir(DIR);
closedir DIR;

# start photoshop
my $ps = Win32::OLE->new('Photoshop.Application') or die $!;
$ps->{Visible} = 0;

foreach my $image_file(@files){

  $image_file = $dir.'/'.$image_file;

  # open image
  my $desc = $ps->MakeDescriptor();
  my $control = $ps->MakeControlObject();
  $desc->PutPath(phKeyNull,$image_file);
  $control->Play(phEventOpen,$desc,phDialogSilent);

  # autolevels
  $desc = $ps->MakeDescriptor();
  $control = $ps->MakeControlObject();
  $desc->PutBoolean(phKeyAuto, 1);
  $control->Play(phEventLevels,$desc,phDialogSilent);

  # resize image
  $desc = $ps->MakeDescriptor();
  $control = $ps->MakeControlObject();
  $desc->PutUnitDouble(phKeyWidth, phUnitPixels, $size);
  $desc->PutBoolean(phKeyConstrainProportions, 1);
  $desc->PutEnumerated(phKeyInterfaceIconFrameDimmed,phTypeInterpolation,phEnumBicubic);
  $control->Play(phEventImageSize,$desc,phDialogSilent);

  $control = $ps->MakeControlObject();
  my $d1 = $ps->MakeDescriptor();
  my $d2 = $ps->MakeDescriptor();
  $d2->PutEnumerated(phKeyPNGInterlaceType,phTypePNGInterlaceType,phEnumPNGInterlaceNone);
  $d2->PutEnumerated(phKeyPNGFilter,phTypePNGFilter,phEnumPNGFilterAdaptive);
  $d1->PutObject(phKeyAs,phClassPNGFormat,$d2);

  (my $outfile = File::Spec->rel2abs($image_file)) =~ s/\.+[^\.]+$/_thumb${size}.png/;
  $outfile =~ s/\s//g;
  print $outfile,"\n";

  $d1->PutPath(phKeyIn,$outfile);
  $d1->PutBoolean(phKeyLowerCase, 1);
  $control->Play(phEventSave,$d1,phDialogSilent);

  $desc = $ps->MakeDescriptor();
  $control = $ps->MakeControlObject();
  $control->Play(phEventClose,$desc,phDialogSilent);
}

$ps->Quit();

Ergänzungen, Kommentare

---+++ Main.??? - 14 Jul 2003 - Betreff